#!/bin/csh -f

set freq1=88544
set freq2=89101
set inname=n44
set outname=n44
alias deconv.csh ../../../scripts/deconv.csh
alias idl /Applications/exelis/idl82/bin/idl

goto start

# Map the HCN & HCO+ data:
if (-e deconv.log) mv deconv.log deconv.bak.log
rm -f mossdi.log
foreach freq ($freq1 $freq2)
	foreach reg (r1 r2)
		foreach file (../20*/${inname}*${reg}*.$freq.cal)
			set dir = $file:h:t
			rm -f $dir.$reg.$freq.cal
			ln -s $file $dir.$reg.$freq.cal
		end
		deconv.csh freq=$reg.$freq start=invert doself=n outfile=$outname.$reg.$freq \
			vfirst=265 vlast=295 interact=n delv=0.4 msklev=3 usemaj=6.7 usemin=5.8 usepa=75
		deconv.csh freq=$reg.$freq start=cleanup doself=n outfile=$outname.$reg.$freq
    end
end
goto end

start:
# Generate the moment maps:
foreach reg (r1 r2)
idl<<EOF
makemom,'$outname.$reg.$freq2.cmmsk.fits',errfile='$outname.$reg.$freq2.cmnse.fits',baseroot='$outname.${reg}_hcop_dil',thresh=3,edge=2,/PVMOM0
makemom,'$outname.$reg.$freq2.cmmsk.fits',errfile='$outname.$reg.$freq2.cmnse.fits',baseroot='$outname.${reg}_hcop_smo',thresh=3.5,edge=2,smopar=[9,5],/PVMOM0
makemom,'$outname.$reg.$freq1.cmmsk.fits',errfile='$outname.$reg.$freq1.cmnse.fits',baseroot='$outname.${reg}_hcn_dil',thresh=3,edge=2,/PVMOM0
makemom,'$outname.$reg.$freq1.cmmsk.fits',errfile='$outname.$reg.$freq1.cmnse.fits',baseroot='$outname.${reg}_hcn_smo',thresh=3.5,edge=2,smopar=[9,5],/PVMOM0
EOF
end
#goto end

# Generate pdf files:
foreach type (mom01 mom0pv)
	set pdflist=()
	foreach file (${outname}*${type}.eps)
		if ($type == 'mom01') then
			epspdf $file
			echo "$file" | enscript -r -s 1 -B -i 30 -f Courier-Bold@12 -o- | \
				ps2pdf - | pdftk $file:r.pdf stamp - output output.pdf
		else
			epspdf -b $file
			echo "$file" | enscript -r -s 1 -B -i 82 -f Courier-Bold@12 -o- | \
				ps2pdf - | pdftk $file:r.pdf stamp - output output.pdf
		endif
		if (-e output.pdf) mv output.pdf $file:r.pdf
		set pdflist=($pdflist $file:r.pdf)
	end
	if ($#pdflist != 0) then
		gs -q -dSAFER -dNOPAUSE -dBATCH -sOutputFile=$type.pdf \
			-sDEVICE=pdfwrite -c .setpdfwrite -f $pdflist
		echo Plotted images output to $type.pdf
		rm -f $pdflist
	endif
end
goto end

end: